Casio Basic入門53

Casio Basic入門

<目次>

---

誤字脱字・記載ミスや分かりにくい表現は随時追記・修正します

追記修正 2017/10/25

 4. CasioBasicを使ってみる（続き）

Chapter 9 - 初級

前回： Casio Basic入門52 を見る


◆ Chapter 9 の目標： 簡単な換算プログラム - 入力ボックスの活用


Chapter 9-3 
fx-5800P での３桁区切り表示を高速化する

前回作った３桁区切りできる複利計算プログラムを再掲します。

・サブルーチン： 3DIGIT
・メインルーチン： COMPINT2

ファイル名: 3DIGIT
Z=0⇒Retuen
Int(log(Z))+1→D
D-3Int(D÷3)→F

For 1→I To D
Int(Z÷10^(D-I))→C
Locate X+I-1,Y,C
Z-C10^(D-I)→Z
If I-3Int(I÷3)=F
Then Isz X
I<D⇒Locate X+I-1,Y,","
IfEnd
Next


ファイル名： COMPINT2
Locate 1,1,"1-C:"
Locate 1,2,"2-R:"
Locate 10,2,"3-Y:"
Locate 1,3,"TOTAL"
Locate 1,4,"MONTH"

0→B:0→R:0→N:0→T:0→M

Do

0→K:Do
Getkey→K
LpWhile K=0
K=73⇒Break

If K=35
Then
5→X:1→Y:8→D:1→E
Locate X,Y,"　　　　　 "　(スペース１１個)
Prog "INP":Z→B
Prog "3DIGIT"
Else If K=36
Then
5→X:2→Y:4→D:1→E
Prog "INP":Z→R
Else If K=37
Then
14→X:2→Y:3→D:1→E
Prog "INP":Z→N
IfEnd:IfEnd
IfEnd

If BRN:Then
Int(B(1+R÷100)^(N))→T
Locate 7,3,"　　　　 "　(スペース１０個)
T→Z:7→X:3→Y
Prog "3DIGIT"
Int(T÷N÷12)→M
Locate 7,4,"　　　　 "　(スペース１０個)
M→Z:7→X:4→Y
Prog "3DIGIT"
IfEnd

LpWhile 1
Cls
Locate 7,2,"BYE!"

---

▋前回のプログラムと高速化の試み

以下のように、３桁区切りで表示ができましたが、

 

左から右へ、パラパラと表示されて時間がかかります。

今回のプログラムで一番動作時間がかかるのは、Locate コマンドです。そして、For ループで Locate が何度も実行されているので、表示に時間がかかると考えています。このプログラムでは、例えば 12345678 を表示するには Locate を１０回実行しています。

そこで、表示を高速化するには、Locate が実行される回数を減らせば良いことになります。

私が最初に考えたのは、例えば 12345678 を 12,345,678 として表示するために Locate を使って、

1) 12 を表示
2) ,（コンマ）を表示
3) 345 を表示
4) ,（コンマ）を表示
5) 678 を表示

つまり、Locate 実行の回数が１０回から５回へ半減しますので、良さそうです。実際に作ってみると、問題がありました。

それは、例えば 139096 を３桁区切りにすると 139,096 となるべきところ、そうはならないバグです。文字列を使えない fx-5800P で数値を出力する時に避けられない問題でした [2017/11/06 校正]。

上の考え方だと

1) 139 を表示⇒問題なし
2) ,（コンマ）を表示⇒問題なし
3) 096 を表示⇒問題発生

Locate コマンドで 数値 096 を表示すると 96 になってしまいます。
つまり、３桁区切りの表示が 139,96 と妙なことになります。

fx-5800P Casio Basic では文字列を扱うコマンドが無いので、096 を一旦文字列に変換して Locate で表示することができません。
ただし、この問題は簡単に解決できます。096 は、３桁でなくて２桁なので、３桁未満の時は文字 "0" を先に表示してから３桁未満の数値を表示すれば良いだけです。

あるいは、先に文字列 "000" を表示した上に 必要な桁から２桁か２桁の数値を上書きする方法もあります。 
過去の Casio Basic 入門でも、この方法は使っています。

但しこれらの方法では、ある所定の数値の場合に Locate の実行回数を減らすことができずい、本質的な解決策とはならない中途半端な方法だと考えました。

そんなわけで、表示に時間がかかるものの、ロジックとしては素直でコンパクトな前回のプログラムを紹介したわけです。

---

▋３桁表示の高速化

sentaro 様から面白いロジックをご提案頂き、それを紹介したいと思います。これは、３桁区切りをチョット巧妙に実現するものです。そのロジックやプログラムの実装方法は初級というよりも中級に入るかも知れません。

例えば 12345678 を表示する前に、コンマが入るところに 0 を入れた数値を作って、

1203450678

として、一旦この数値を Locate で表示します。

次に、コンマが入るところの 0 を ,（コンマ）で上書きして（Locate コマンド使用）、

12,345,678

とすれば良い．．．といった考え方です。私には思いつかなかった面白いものです。

この８桁の数値を３桁区切り表示する時の Locate 実行回数は３回になって、激減します（前回のプログラムだと１０回実行）。

このロジックだと、上で問題が発生した 139096 の場合は、一旦 1390096 に変換して、この数値を Locate で表示。続いてコンマが入るべき 0 の位置に Locate で , （コンマ）を上書きするので、

139,096

と正しく表示されます。

なかなかよく考えられたロジックですね。

前回作ったプログラムでは、Locate を７回実行するところ、２回で済むので、表示が大いに高速化されます。

---

▋新ロジックの実装

そこで、３桁区切り表示を行うサブルーチン 3DIGIT を 3DIGIT2 とします。
メインルーチンは、COMPINT2 を COMPINT3 にします。


プログラムを以下に示します。

・サブルーチン： 3DIGIT2
・メインルーチン： COMPINT3

ファイル名: 3DIGIT2
Z=0⇒Retuen
Int(log(Z))+1→K
(K≥4)+(K≥7)+(K≥10)→I
Frac(Z÷1x₁₀3)×1x₁₀3→U
Int(Frac(Z÷1x₁₀6)×1x₁₀3)→V
Int(Frac(Z÷1x₁₀9)×1x₁₀3)→W
Int(Z÷1x₁₀9)→D

If K≤8:Than
Locate X,Y,1x₁₀8×W+1x₁₀4×V+U
I≥1⇒Locate X+K-2-(I=1),Y,","
I≥2⇒Locate X+K-6,Y,","
Else
Locate X+K-6+(I≥3),Y,1x₁₀7+1x₁₀4×V+W
Locate X,Y,1x₁₀4×D+W
Locate X+K-2+(I≥3),Y,","
Locate X+K-6+(I≥3),Y,","
I≥3⇒Locate X+K-9,Y,","
IfEnd


変数の説明：
入力値: Z
X座標： X
Y座標： Y

ワーク変数　U:下３桁
ワーク変数　V:中３桁
ワーク変数　W:上３桁
ワーク変数　D:最上位１桁
ワーク変数　K数値の桁数
ワーク変数　I:三桁区切り文字の数


ここで、解説を２つだけ．．．


▶ 青文字の( ) の部分

この ( ) は、０か１かの値になります。( ) の中が正しいなら（真ならば）１、正しくなければ（偽ならば）０になります。この性質をうまく使って計算式に中で利用しています。


▶ 赤文字 x₁₀4 の表記

これは [x10^x] キーを押して入力します。


メインルーチンは、呼び出すサブルーチン名を変更するだけ．．．

ファイル名： COMPINT3
Locate 1,1,"1-C:"
Locate 1,2,"2-R:"
Locate 10,2,"3-Y:"
Locate 1,3,"TOTAL"
Locate 1,4,"MONTH"

0→B:0→R:0→N:0→T:0→M

Do

0→K:Do
Getkey→K
LpWhile K=0
K=73⇒Break

If K=35
Then
5→X:1→Y:8→D:1→E
Locate X,Y,"　　　　　 "　(スペース１１個)
Prog "INP":Z→B
Prog "3DIGIT2"
Else If K=36
Then
5→X:2→Y:4→D:1→E
Prog "INP":Z→R
Else If K=37
Then
14→X:2→Y:3→D:1→E
Prog "INP":Z→N
IfEnd:IfEnd
IfEnd

If BRN:Then
Int(B(1+R÷100)^(N))→T
Locate 7,3,"　　　　 "　(スペース１０個)
T→Z:7→X:3→Y
Prog "3DIGIT2"
Int(T÷N÷12)→M
Locate 7,4,"　　　　 "　(スペース１０個)
M→Z:7→X:4→Y
Prog "3DIGIT2"
IfEnd

LpWhile 1
Cls
Locate 7,2,"BYE!"


３桁区切りでの表示が劇的に速くなりました。
コードを眺めて、プログラムの巧妙さを楽しんでください。

---

fx-5800P の Casio Basic には文字列処理の機能がありませんが、工夫次第で色々と実現できるわけで、逆に言えば Casio Basic がそれだけ高機能だとも言えますね。



つづく．．．

⇒ Casio Basic入門５４ / Casio Basic入門G01 / 目次



応援クリックをお願いします。励みになるので．．．

にほんブログ村

人気ブログランキング

FC2ブログランキングへ

 




keywords: fx-5800P、CasioBasic、入力ボックス, プログラミング入門、プログラム関数電卓

---

リンク集　|　ブログ内マップ